Closing open Lotus Notes file

Koen Vermoesen — Mon, 03 Nov 2008 14:06:46 +0000

The users at a certain customer have a problem with reopening Lotus Notes if their session is not closed properly (e.g. because of a crash of a terminal server). They keep receiving the error message “Domino Server still running” until we close the open files.

I’ve been writing a script over time to automate this process which becomes quickly annoying after you’ve done it a couple of times.

More specifically, the script will:

Connect to a GC to get domain and display name (ADFind)
Connect to a DC to get home directory (ADFind)
Derive server name from the previous query via string manipulation (Set)
Kill PsExec if it’s already running (SC)
Find the physical disk (PsExec)
List open Notes files and ask if you whan to close them (PsFile)
Close the files if after you confirmed you wanted to do so (PsFile)
Quit
Last but not least, it will put a comment on the clipboard for easy pasting in the incident management tool ;-)

Prerequisites are both ADFind and PsTools.

Well, here it is:

::========================================================================================================
:: AUTHOR
::    Koen Vermoesen
::    koen.vermoesen@nospam.com
::    2008-04-24
::========================================================================================================
:: SCRIPT
::    Close open lotus notes files
::========================================================================================================
:: PREREQUISITES
::    ADFind    http://www.joeware.net/freetools/tools/adfind/index.htm
::    PsTools    http://technet.microsoft.com/en-us/sysinternals/bb896649.aspx
::========================================================================================================
:: CHANGE HISTORY:
::    2008-04-24 Initial version
::    2008-04-25 Use %temp% to avoid writing to a network share all the time
::    2008-05-07 Added a todo for the script
::    2008-05-13 Call another script to verify & close psexec if it's already running
::    2008-05-13 Goto end (skip closing)  when no open files found
::    2008-05-13 Print user's diplay name as a means to cross check
::    2008-05-14 Removed last reference to temporary file
::    2008-07-31 Started using ADFind to make script work across domains
::    2008-07-31 Removed dependency on other scripts for easy sharing with colleagues
::    2008-09-16 Goto end after closing files + use variable for Title
::    2008-10-06 Provide some help when no parameters are being passed
::    2008-10-07 Used hardcoded path for DFS
::    2008-10-07 Check if very first query returns a valid resullt. Jump to help (skip remainder of script) if not
::    2008-10-07 Update Help: hardcoded DFS values + for loop example for running against a batch of users
::    2008-10-27 Use clip.exe to store some comment on the clipboard for easy pasting in the incident
::========================================================================================================
:: TO DO
::    Integrate logic for working on a batch of users.
::========================================================================================================
  
@echo off
setlocal EnableDelayedExpansion
  
:: Setting some variables
Set StrTitle=Close open Lotus Notes files
Set strHomeDirAB=FileServer01
Set strHardDiskAB=E:
  
Cls
Title %StrTitle%
  
::Saving the input parameter to variable
Set StrUserName=%1
If "[%strUserName%]"=="[]" Goto Help
Set Return=return1
Goto SubEcho
:return1
  
:: Looking up Distinguished Name & Display Name
For /F "tokens=1,2 delims=;" %%I in ('adfind -nodn -csv -nocsvheader -csvnoq -csvdelim ^; -gc -s subtree -b dc^=domain^,dc^=tld -f ^"sAMAccountName^=%StrUserName%^" distinguishedName displayName') Do Set StrDistingName=%%I & Set StrDisplayName=%%J
If "[%StrDisplayName%]"=="[]" Echo. & Echo No valid user object found; please check the username. & Echo. & Goto Help
Set StrBaseDN=%StrDistingName:~-26%
Set Return=return2
Goto SubEcho
:return2
  
:: Looking up Home Directory
Set StrTLD=%StrBaseDN:~22,3%
Set StrRoot=%StrBaseDN:~15,3%
Set StrDomain=%StrBaseDN:~3,8%
For /F %%I in ('adfind -nodn -csv -nocsvheader -csvnoq -s subtree -b dc^=%StrDomain%^,dc^=%StrRoot%^,dc^=%StrTLD% -f ^"sAMAccountName^=%StrUserName%^" homeDirectory') Do Set StrHomeDirectory=%%I
Set Return=return3
Goto SubEcho
:return3
  
:: Looking up Home Server
IF /I "%StrDomain%"=="subdomain3" (Set StrHomeServer=%strHomeDirAB%) Else (For /F "tokens=1 delims=\" %%I in ("%StrHomeDirectory%") Do Set StrHomeServer=%%I)
Set Return=return4
Goto SubEcho
:return4
  
:: Ensuring PsExec is not running on Home Server
echo.
For /F "Tokens=2" %%I in ('sc \\%StrHomeServer% query psexesvc ^| find "SERVICE_NAME"') Do Set StrPsexecExists=%%I
If /I "%StrPsexecExists%"=="psexesvc" (echo PsExec running on the remote host; killing it. & sc \\%StrHomeServer% stop psexesvc & sc \\%StrHomeServer% delete psexesvc) else (echo PsExec is not running on the remote host.)
  
:: Looking up Physical Disk
echo.
IF /I "%StrDomain%"=="subdomain3" (Set StrHardDisk=%strHardDiskAB%) Else (For /F "tokens=2 delims=\ " %%I in ('psexec \\%StrHomeServer% net share ^| find /i "%StrUserName%"') Do Set StrHardDisk=%%I)
Set Return=return5
Goto SubEcho
:return5
  
:: Listing open Lotus Notes Files
IF /I "%StrDomain%"=="subdomain1" (set StrNotesPath=%StrHardDisk%\folder\%StrUserName%\windows\NotesR6)
IF /I "%StrDomain%"=="subdomain2" (set StrNotesPath=%StrHardDisk%\folder\folder\%StrUserName%\notes\data)
IF /I "%StrDomain%"=="subdomain3" (set StrNotesPath=%StrHardDisk%\folder\%StrUserName%\WINDOWS\NotesR6)
Set StrOpenFiles=
For /F "tokens=2 delims=] " %%I in ('psfile \\%StrHomeServer% %StrNotesPath% ^| find /i "] %StrNotesPath%"') Do Set StrOpenFiles=!StrOpenFiles!%%I   
Set Return=return6
Goto SubEcho
:return6
echo.
IF /I "%StrOpenFiles%"=="" (Echo No open files found. & goto :end)
echo Open Files:
For %%I in (%StrOpenFiles%) do echo %%I
  
:: Closing open Lotus Notes Files
echo.
Set /P StrConfirmClose="Press  to close these files,  key will SKIP this step."
IF /I "%StrConfirmClose%"=="c" (psfile \\%StrHomeServer% %StrNotesPath% -c) ELSE Goto end
Set Return=return7
Goto SubEcho
:return7
echo.
echo Open Lotus Notes files closed!
echo Open Lotus Notes files for user %StrUserName% on server %StrHomeServer% closed. | clip
Goto End
  
:: Procedure printing the different values determined by script
:SubEcho
cls
Title %StrTitle%
Echo User:        %StrUserName%
Echo Name:        %StrDisplayName%
Echo BaseDN:        %StrBaseDN%
Echo TLD:        %StrTLD%
Echo Root:        %StrRoot%
Echo Domain:        %StrDomain%
Echo HomeDir:    %StrHomeDirectory%
Echo Server:        %StrHomeServer%
Echo Disk:        %StrHardDisk%
Echo Path:        %StrNotesPath%
Goto %Return%
  
:Help
Title %strTitle%
Echo You should call this script from the command line passing the name of the user to unblock as a parameter. (e.g. "killnotes user1980"). The script will then fetch some data, list the open lotus notes files and ask you wheter or not you want to close them.
Echo.
Echo More specifically, the script will:
Echo   1. Connect to GC to get domain and display name (ADFind)
Echo   2. Connect to DC to get home directory (ADFind)
Echo   3. Get servername via string manipulation (Set)
Echo   4. Kill PsExec if it's already running (SC)
Echo   5. Find the physical disk (PsExec)
Echo   6. List open Notes files and ask if you whan to close them (PsFile)
Echo   7. Close the files if you confirmed you wanted to do so (PsFile)
Echo   8. Quit
Echo.
Echo If you want to apply this script on a number of users then I recommend saving them in a file "userlist.txt" (1 user per line). You can then use a for loop to launch the script:
Echo.
Echo   for /F %%i in (userlist.txt) do killnotes %%i
Echo.
Echo IMPORTANT: Physical Disk (%strHardDiskAB%) and Server Name (%strHomeDirAB%) for AB are HARDCODED. These values need to be adopted in the script if the design ever changes.
Echo.
Echo PS1: The script will print the values of the different variables to allow you to monitor the progress.
Echo PS2: If the script halts for a moment it's because of number of connections being made using PsTools.
Echo.
  
::Deleting variables
:END
Echo.
Echo Quitting...
Endlocal

There’s still some room for improvement obviously. The hard coded DFS information, for instance, should be replaced with some decent logic (there are very few users on this infra however, so I didn’t invest to much time in that part).

http://www.robvanderwoude.com/ proved very helpful while writing this script.

Posted in Scripting Tagged: Batch, LotusNotes

KillPsExec.bat

Koen Vermoesen — Mon, 19 May 2008 10:15:29 +0000

I’m using PsTools a lot for the moment. These nifty command line tools prove very efficient for remotely administering a bunch of servers (e.g. checking the state of a service or restarting it).

One of the drawbacks however is that the different versions of these tools don’t always seem to cooperate very well. A lengthy and time consuming solution is to use Hyena to remove the psexesvc service.

The little script below relies on SC to get that done a lot quicker. It basically checks if the psexesvc service exists and kills it if it does.

@echo off
cls

:: Checking & removing psexec from the remote host
For /F “Tokens=2″ %%I in (‘sc \\%1 query psexesvc ^| find “SERVICE_NAME”‘) Do Set StrPsexecExists=%%I
If /I “[%StrPsexecExists%]“==”[psexesvc]” (echo PsExec running on the remote host; killing it. & sc \\%1 stop psexesvc & sc \\%1 delete psexesvc) else (echo PsExec is not running on the remote host.)

The script accepts 1 input parameter; the computer name.

Apart from using the caret (“^”) to escape the pipe (“|”) there’s nothing special about it. I’m mainly blogging about it because it’s called in some other script I’d like to write about later on.

Alfa BBT » Batch

Split CSV to TXT

Closing open Lotus Notes file

KillPsExec.bat

ConvertUNC2URL.bat